Section 6.4 examples using Maple.

New commands:

6.1: Maple can perform a Laplace transform and inverse transform: laplace(f(t),t,s)

invlaplace(F(s),s,t)

We must call in "inttrans" (for integral transforms): with(inttrans)

6.3, 6.4: u(t-c) from the text is Heaviside(t-c) in Maple.

Exercises from 6.3 and 6.4:

with(plots): with(inttrans):

6.3.15: Find the Laplace transform of the function f(t) (given in piecewise form)

f:=(Heaviside(t-Pi)-Heaviside(t-2*Pi))*(t-Pi);

plot(f,t=0..8);

F:=laplace(f,t,s);

6.3.23: Find the inverse Laplace transform of the given expression

F:=(s-2)/(s^2-4*s+3);

F1:=convert(F,parfrac,s);

F2:=invlaplace(exp(-s)*F1,s,t);

Section 6.4 Examples follow (Exercises 3, 10, 17)

#Exercise 6.4.3 G:=sin(t)-sin(t-2*Pi)*Heaviside(t-2*Pi); #Forcing function

DE03:=diff(y(t),t$2)+4*y(t);

#We can solve the DE "manually" if we want- Here is how you do it! Eqn03:=DE03=G;

Eqn03A:=laplace(Eqn03,t,s);

Eqn03B:=solve(Eqn03A,laplace(y(t),t,s));

Eqn03C:=subs({y(0)=0,D(y)(0)=0},Eqn03B);

Eqn03D:=invlaplace(Eqn03C,s,t);

plot({G,Eqn03D},t=0..3*Pi);

Here we show the solution to Exercise 10 using Maple's built-in solver:

G:=sin(t)*(1-Heaviside(t-Pi));

DE10:=diff(y(t),t$2)+diff(y(t),t)+(5/4)*y(t);

Y1:=simplify(rhs(dsolve({DE10=G,y(0)=0,D(y)(0)=0},y(t),method='laplace')));

plot({G,Y1},t=0..3*Pi);

We might do this "manually" to see if Y1 is actually a nicer expression:

Eqn10A:=DE10=G;

Eqn10B:=laplace(Eqn10A,t,s);

Eqn10C:=subs({y(0)=0,D(y)(0)=0},Eqn10B);

Eqn10D:=solve(Eqn10C,laplace(y(t),t,s));

F:=4/((s^2+1)*(4*s^2+4*s+5));

F1:=convert(F,parfrac,s);

Y1A:=invlaplace(F1,s,t);

Y2A:=invlaplace(F1*exp(-s*Pi),s,t);

Y:=Y1A+Y2A;

plot({G,Y},t=0..3*Pi);

Looking at Exercise 17

assume(k>0);

F:=(1/k)*(Heaviside(t-5)*(t-5)-Heaviside(t-5-k)*(t-5-k));

DE17:=diff(y(t),t$2)+4*y(t)=F;

Eqn17:=laplace(DE17,t,s);

Eqn17A:=solve(Eqn17,laplace(y(t),t,s));

Eqn17B:=subs({y(0)=0,D(y)(0)=0},Eqn17A);

H:=1/(k*s^2*(s^2+4));

H1:=convert(H,parfrac,s);

Yk:=invlaplace(H1*(exp(-5*s)-exp(-(5+k)*s)),s,t);

Y1:=subs(k=2,Yk);

plot(Y1,t=0..30);

Y2:=subs(k=5,Yk);

plot({Y1,Y2},t=0..30);

Y3:=subs(k=10,Yk);

plot({Y1,Y2,Y3},t=0..30);

ExpA:=(1/(8*k))*( (2*t-sin(2*(t-5))-10) - (-2*k+2*t-sin(2*(t-5-k))-10) );

simplify(ExpA);

# To answer the remaining questions, it's easiest to use a formula for sin(A)+sin(B)